Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

perlfaq7

Perl 5 version 12.2 documentation
Go to top
Show page index • Show recent pages
Recently read

perlfaq7

NAME

perlfaq7 - General Perl Language Issues

DESCRIPTION

This section deals with general Perl language issues that don't clearly fit into any of the other sections.

Can I get a BNF/yacc/RE for the Perl language?

There is no BNF, but you can paw your way through the yacc grammar in perly.y in the source distribution if you're particularly brave. The grammar relies on very smart tokenizing code, so be prepared to venture into toke.c as well.

In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF. The work of parsing perl is distributed between yacc, the lexer, smoke and mirrors."

What are all these $@%&* punctuation signs, and how do I know when to use them?

They are type specifiers, as detailed in perldata:

  1. 	$ for scalar values (number, string or reference)
  2. 	@ for arrays
  3. 	% for hashes (associative arrays)
  4. 	& for subroutines (aka functions, procedures, methods)
  5. 	* for all types of that symbol name.  In version 4 you used them like
  6. 	  pointers, but in modern perls you can just use references.

There are couple of other symbols that you're likely to encounter that aren't really type specifiers:

  1. 	<> are used for inputting a record from a filehandle.
  2. 	\  takes a reference to something.

Note that <FILE> is neither the type specifier for files nor the name of the handle. It is the <> operator applied to the handle FILE. It reads one line (well, record--see $/ in perlvar) from the handle FILE in scalar context, or all lines in list context. When performing open, close, or any other operation besides <> on files, or even when talking about the handle, do not use the brackets. These are correct: eof(FH), seek(FH, 0, 2) and "copying from STDIN to FILE".

Do I always/never have to quote my strings or use semicolons and commas?

Normally, a bareword doesn't need to be quoted, but in most cases probably should be (and must be under use strict ). But a hash key consisting of a simple word (that isn't the name of a defined subroutine) and the left-hand operand to the => operator both count as though they were quoted:

  1. 	This                    is like this
  2. 	------------            ---------------
  3. 	$foo{line}              $foo{'line'}
  4. 	bar => stuff            'bar' => stuff

The final semicolon in a block is optional, as is the final comma in a list. Good style (see perlstyle) says to put them in except for one-liners:

  1. 	if ($whoops) { exit 1 }
  2. 	@nums = (1, 2, 3);
  4. 	if ($whoops) {
  5. 		exit 1;
  6. 	}
  8. 	@lines = (
  9. 	"There Beren came from mountains cold",
  10. 	"And lost he wandered under leaves",
  11. 	);

How do I skip some return values?

One way is to treat the return values as a list and index into it:

  1. 	$dir = (getpwnam($user))[7];

Another way is to use undef as an element on the left-hand-side:

  1. 	($dev, $ino, undef, undef, $uid, $gid) = stat($file);

You can also use a list slice to select only the elements that you need:

  1. 	($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];

How do I temporarily block warnings?

If you are running Perl 5.6.0 or better, the use warnings pragma allows fine control of what warning are produced. See perllexwarn for more details.

  1. 	{
  2. 	no warnings;          # temporarily turn off warnings
  3. 	$a = $b + $c;         # I know these might be undef
  4. 	}

Additionally, you can enable and disable categories of warnings. You turn off the categories you want to ignore and you can still get other categories of warnings. See perllexwarn for the complete details, including the category names and hierarchy.

  1. 	{
  2. 	no warnings 'uninitialized';
  3. 	$a = $b + $c;
  4. 	}

If you have an older version of Perl, the $^W variable (documented in perlvar) controls runtime warnings for a block:

  1. 	{
  2. 	local $^W = 0;        # temporarily turn off warnings
  3. 	$a = $b + $c;         # I know these might be undef
  4. 	}

Note that like all the punctuation variables, you cannot currently use my() on $^W , only local().

What's an extension?

An extension is a way of calling compiled C code from Perl. Reading perlxstut is a good place to learn more about extensions.

Why do Perl operators have different precedence than C operators?

Actually, they don't. All C operators that Perl copies have the same precedence in Perl as they do in C. The problem is with operators that C doesn't have, especially functions that give a list context to everything on their right, eg. print, chmod, exec, and so on. Such functions are called "list operators" and appear as such in the precedence table in perlop.

A common mistake is to write:

  1. 	unlink $file || die "snafu";

This gets interpreted as:

  1. 	unlink ($file || die "snafu");

To avoid this problem, either put in extra parentheses or use the super low precedence or operator:

  1. 	(unlink $file) || die "snafu";
  2. 	unlink $file or die "snafu";

The "English" operators (and , or , xor , and not ) deliberately have precedence lower than that of list operators for just such situations as the one above.

Another operator with surprising precedence is exponentiation. It binds more tightly even than unary minus, making -2**2 produce a negative not a positive four. It is also right-associating, meaning that 2**3**2 is two raised to the ninth power, not eight squared.

Although it has the same precedence as in C, Perl's ?: operator produces an lvalue. This assigns $x to either $a or $b, depending on the trueness of $maybe:

  1. 	($maybe ? $a : $b) = $x;

How do I declare/create a structure?

In general, you don't "declare" a structure. Just use a (probably anonymous) hash reference. See perlref and perldsc for details. Here's an example:

  1. 	$person = {};                   # new anonymous hash
  2. 	$person->{AGE}  = 24;           # set field AGE to 24
  3. 	$person->{NAME} = "Nat";        # set field NAME to "Nat"

If you're looking for something a bit more rigorous, try perltoot.

How do I create a module?

(contributed by brian d foy)

perlmod, perlmodlib, perlmodstyle explain modules in all the gory details. perlnewmod gives a brief overview of the process along with a couple of suggestions about style.

If you need to include C code or C library interfaces in your module, you'll need h2xs. h2xs will create the module distribution structure and the initial interface files you'll need. perlxs and perlxstut explain the details.

If you don't need to use C code, other tools such as ExtUtils::ModuleMaker and Module::Starter, can help you create a skeleton module distribution.

You may also want to see Sam Tregar's "Writing Perl Modules for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 ) which is the best hands-on guide to creating module distributions.

How do I adopt or take over a module already on CPAN?

(contributed by brian d foy)

The easiest way to take over a module is to have the current module maintainer either make you a co-maintainer or transfer the module to you.

If you can't reach the author for some reason (e.g. email bounces), the PAUSE admins at modules@perl.org can help. The PAUSE admins treat each case individually.

  • Get a login for the Perl Authors Upload Server (PAUSE) if you don't already have one: http://pause.perl.org

  • Write to modules@perl.org explaining what you did to contact the current maintainer. The PAUSE admins will also try to reach the maintainer.

  • Post a public message in a heavily trafficked site announcing your intention to take over the module.

  • Wait a bit. The PAUSE admins don't want to act too quickly in case the current maintainer is on holiday. If there's no response to private communication or the public post, a PAUSE admin can transfer it to you.

How do I create a class?

(contributed by brian d foy)

In Perl, a class is just a package, and methods are just subroutines. Perl doesn't get more formal than that and lets you set up the package just the way that you like it (that is, it doesn't set up anything for you).

The Perl documentation has several tutorials that cover class creation, including perlboot (Barnyard Object Oriented Tutorial), perltoot (Tom's Object Oriented Tutorial), perlbot (Bag o' Object Tricks), and perlobj.

How can I tell if a variable is tainted?

You can use the tainted() function of the Scalar::Util module, available from CPAN (or included with Perl since release 5.8.0). See also Laundering and Detecting Tainted Data in perlsec.

What's a closure?

Closures are documented in perlref.

Closure is a computer science term with a precise but hard-to-explain meaning. Usually, closures are implemented in Perl as anonymous subroutines with lasting references to lexical variables outside their own scopes. These lexicals magically refer to the variables that were around when the subroutine was defined (deep binding).

Closures are most often used in programming languages where you can have the return value of a function be itself a function, as you can in Perl. Note that some languages provide anonymous functions but are not capable of providing proper closures: the Python language, for example. For more information on closures, check out any textbook on functional programming. Scheme is a language that not only supports but encourages closures.

Here's a classic non-closure function-generating function:

  1. 	sub add_function_generator {
  2. 		return sub { shift() + shift() };
  3. 		}
  5. 	$add_sub = add_function_generator();
  6. 	$sum = $add_sub->(4,5);                # $sum is 9 now.

The anonymous subroutine returned by add_function_generator() isn't technically a closure because it refers to no lexicals outside its own scope. Using a closure gives you a function template with some customization slots left out to be filled later.

Contrast this with the following make_adder() function, in which the returned anonymous function contains a reference to a lexical variable outside the scope of that function itself. Such a reference requires that Perl return a proper closure, thus locking in for all time the value that the lexical had when the function was created.

  1. 	sub make_adder {
  2. 		my $addpiece = shift;
  3. 		return sub { shift() + $addpiece };
  4. 	}
  6. 	$f1 = make_adder(20);
  7. 	$f2 = make_adder(555);

Now &$f1($n) is always 20 plus whatever $n you pass in, whereas &$f2($n) is always 555 plus whatever $n you pass in. The $addpiece in the closure sticks around.

Closures are often used for less esoteric purposes. For example, when you want to pass in a bit of code into a function:

  1. 	my $line;
  2. 	timeout( 30, sub { $line = <STDIN> } );

If the code to execute had been passed in as a string, '$line = <STDIN>' , there would have been no way for the hypothetical timeout() function to access the lexical variable $line back in its caller's scope.

Another use for a closure is to make a variable private to a named subroutine, e.g. a counter that gets initialized at creation time of the sub and can only be modified from within the sub. This is sometimes used with a BEGIN block in package files to make sure a variable doesn't get meddled with during the lifetime of the package:

  1. 	BEGIN {
  2. 		my $id = 0;
  3. 		sub next_id { ++$id }
  4. 	}

This is discussed in more detail in perlsub, see the entry on Persistent Private Variables.

What is variable suicide and how can I prevent it?

This problem was fixed in perl 5.004_05, so preventing it means upgrading your version of perl. ;)

Variable suicide is when you (temporarily or permanently) lose the value of a variable. It is caused by scoping through my() and local() interacting with either closures or aliased foreach() iterator variables and subroutine arguments. It used to be easy to inadvertently lose a variable's value this way, but now it's much harder. Take this code:

  1. 	my $f = 'foo';
  2. 	sub T {
  3. 		while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
  4. 		}
  6. 	T;
  7. 	print "Finally $f\n";

If you are experiencing variable suicide, that my $f in the subroutine doesn't pick up a fresh copy of the $f whose value is <foo>. The output shows that inside the subroutine the value of $f leaks through when it shouldn't, as in this output:

  1. 	foobar
  2. 	foobarbar
  3. 	foobarbarbar
  4. 	Finally foo

The $f that has "bar" added to it three times should be a new $f my $f should create a new lexical variable each time through the loop. The expected output is:

  1. 	foobar
  2. 	foobar
  3. 	foobar
  4. 	Finally foo

How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?

You need to pass references to these objects. See Pass by Reference in perlsub for this particular question, and perlref for information on references.

  • Passing Variables and Functions

    Regular variables and functions are quite easy to pass: just pass in a reference to an existing or anonymous variable or function:

    1. 	func( \$some_scalar );
    3. 	func( \@some_array  );
    4. 	func( [ 1 .. 10 ]   );
    6. 	func( \%some_hash   );
    7. 	func( { this => 10, that => 20 }   );
    9. 	func( \&some_func   );
    10. 	func( sub { $_[0] ** $_[1] }   );
  • Passing Filehandles

    As of Perl 5.6, you can represent filehandles with scalar variables which you treat as any other scalar.

    1. 	open my $fh, $filename or die "Cannot open $filename! $!";
    2. 	func( $fh );
    4. 	sub func {
    5. 		my $passed_fh = shift;
    7. 		my $line = <$passed_fh>;
    8. 		}

    Before Perl 5.6, you had to use the *FH or \*FH notations. These are "typeglobs"--see Typeglobs and Filehandles in perldata and especially Pass by Reference in perlsub for more information.

  • Passing Regexes

    Here's an example of how to pass in a string and a regular expression for it to match against. You construct the pattern with the qr// operator:

    1. 	sub compare($$) {
    2. 		my ($val1, $regex) = @_;
    3. 		my $retval = $val1 =~ /$regex/;
    4. 	return $retval;
    5. 	}
    6. 	$match = compare("old McDonald", qr/d.*D/i);
  • Passing Methods

    To pass an object method into a subroutine, you can do this:

    1. 	call_a_lot(10, $some_obj, "methname")
    2. 	sub call_a_lot {
    3. 		my ($count, $widget, $trick) = @_;
    4. 		for (my $i = 0; $i < $count; $i++) {
    5. 			$widget->$trick();
    6. 		}
    7. 	}

    Or, you can use a closure to bundle up the object, its method call, and arguments:

    1. 	my $whatnot =  sub { $some_obj->obfuscate(@args) };
    2. 	func($whatnot);
    3. 	sub func {
    4. 		my $code = shift;
    5. 		&$code();
    6. 	}

    You could also investigate the can() method in the UNIVERSAL class (part of the standard perl distribution).

How do I create a static variable?

(contributed by brian d foy)

In Perl 5.10, declare the variable with state. The state declaration creates the lexical variable that persists between calls to the subroutine:

  1. 	sub counter { state $count = 1; $counter++ }

You can fake a static variable by using a lexical variable which goes out of scope. In this example, you define the subroutine counter , and it uses the lexical variable $count . Since you wrap this in a BEGIN block, $count is defined at compile-time, but also goes out of scope at the end of the BEGIN block. The BEGIN block also ensures that the subroutine and the value it uses is defined at compile-time so the subroutine is ready to use just like any other subroutine, and you can put this code in the same place as other subroutines in the program text (i.e. at the end of the code, typically). The subroutine counter still has a reference to the data, and is the only way you can access the value (and each time you do, you increment the value). The data in chunk of memory defined by $count is private to counter .

  1. 	BEGIN {
  2. 		my $count = 1;
  3. 		sub counter { $count++ }
  4. 	}
  6. 	my $start = counter();
  8. 	.... # code that calls counter();
  10. 	my $end = counter();

In the previous example, you created a function-private variable because only one function remembered its reference. You could define multiple functions while the variable is in scope, and each function can share the "private" variable. It's not really "static" because you can access it outside the function while the lexical variable is in scope, and even create references to it. In this example, increment_count and return_count share the variable. One function adds to the value and the other simply returns the value. They can both access $count , and since it has gone out of scope, there is no other way to access it.

  1. 	BEGIN {
  2. 		my $count = 1;
  3. 		sub increment_count { $count++ }
  4. 		sub return_count    { $count }
  5. 	}

To declare a file-private variable, you still use a lexical variable. A file is also a scope, so a lexical variable defined in the file cannot be seen from any other file.

See Persistent Private Variables in perlsub for more information. The discussion of closures in perlref may help you even though we did not use anonymous subroutines in this answer. See Persistent Private Variables in perlsub for details.

What's the difference between dynamic and lexical (static) scoping? Between local() and my()?

local($x) saves away the old value of the global variable $x and assigns a new value for the duration of the subroutine which is visible in other functions called from that subroutine. This is done at run-time, so is called dynamic scoping. local() always affects global variables, also called package variables or dynamic variables.

my($x) creates a new variable that is only visible in the current subroutine. This is done at compile-time, so it is called lexical or static scoping. my() always affects private variables, also called lexical variables or (improperly) static(ly scoped) variables.

For instance:

  1. 	sub visible {
  2. 		print "var has value $var\n";
  3. 		}
  5. 	sub dynamic {
  6. 		local $var = 'local';	# new temporary value for the still-global
  7. 		visible();              #   variable called $var
  8. 		}
  10. 	sub lexical {
  11. 		my $var = 'private';    # new private variable, $var
  12. 		visible();              # (invisible outside of sub scope)
  13. 		}
  15. 	$var = 'global';
  17. 	visible();      		# prints global
  18. 	dynamic();      		# prints local
  19. 	lexical();      		# prints global

Notice how at no point does the value "private" get printed. That's because $var only has that value within the block of the lexical() function, and it is hidden from called subroutine.

In summary, local() doesn't make what you think of as private, local variables. It gives a global variable a temporary value. my() is what you're looking for if you want private variables.

See Private Variables via my() in perlsub and Temporary Values via local() in perlsub for excruciating details.

How can I access a dynamic variable while a similarly named lexical is in scope?

If you know your package, you can just mention it explicitly, as in $Some_Pack::var. Note that the notation $::var is not the dynamic $var in the current package, but rather the one in the "main" package, as though you had written $main::var.

  1. 	use vars '$var';
  2. 	local $var = "global";
  3. 	my    $var = "lexical";
  5. 	print "lexical is $var\n";
  6. 	print "global  is $main::var\n";

Alternatively you can use the compiler directive our() to bring a dynamic variable into the current lexical scope.

  1. 	require 5.006; # our() did not exist before 5.6
  2. 	use vars '$var';
  4. 	local $var = "global";
  5. 	my $var    = "lexical";
  7. 	print "lexical is $var\n";
  9. 	{
  10. 		our $var;
  11. 		print "global  is $var\n";
  12. 	}

What's the difference between deep and shallow binding?

In deep binding, lexical variables mentioned in anonymous subroutines are the same ones that were in scope when the subroutine was created. In shallow binding, they are whichever variables with the same names happen to be in scope when the subroutine is called. Perl always uses deep binding of lexical variables (i.e., those created with my()). However, dynamic variables (aka global, local, or package variables) are effectively shallowly bound. Consider this just one more reason not to use them. See the answer to What's a closure?.

Why doesn't "my($foo) = <FILE>;" work right?

my() and local() give list context to the right hand side of = . The <FH> read operation, like so many of Perl's functions and operators, can tell which context it was called in and behaves appropriately. In general, the scalar() function can help. This function does nothing to the data itself (contrary to popular myth) but rather tells its argument to behave in whatever its scalar fashion is. If that function doesn't have a defined scalar behavior, this of course doesn't help you (such as with sort()).

To enforce scalar context in this particular case, however, you need merely omit the parentheses:

  1. 	local($foo) = <FILE>;	    # WRONG
  2. 	local($foo) = scalar(<FILE>);   # ok
  3. 	local $foo  = <FILE>;	    # right

You should probably be using lexical variables anyway, although the issue is the same here:

  1. 	my($foo) = <FILE>;	# WRONG
  2. 	my $foo  = <FILE>;	# right

How do I redefine a builtin function, operator, or method?

Why do you want to do that? :-)

If you want to override a predefined function, such as open(), then you'll have to import the new definition from a different module. See Overriding Built-in Functions in perlsub. There's also an example in Class::Template in perltoot.

If you want to overload a Perl operator, such as + or ** , then you'll want to use the use overload pragma, documented in overload.

If you're talking about obscuring method calls in parent classes, see Overridden Methods in perltoot.

What's the difference between calling a function as &foo and foo()?

(contributed by brian d foy)

Calling a subroutine as &foo with no trailing parentheses ignores the prototype of foo and passes it the current value of the argument list, @_ . Here's an example; the bar subroutine calls &foo , which prints its arguments list:

  1. 	sub bar { &foo }
  3. 	sub foo { print "Args in foo are: @_\n" }
  5. 	bar( qw( a b c ) );

When you call bar with arguments, you see that foo got the same @_ :

  1. 	Args in foo are: a b c

Calling the subroutine with trailing parentheses, with or without arguments, does not use the current @_ and respects the subroutine prototype. Changing the example to put parentheses after the call to foo changes the program:

  1. 	sub bar { &foo() }
  3. 	sub foo { print "Args in foo are: @_\n" }
  5. 	bar( qw( a b c ) );

Now the output shows that foo doesn't get the @_ from its caller.

  1. 	Args in foo are:

The main use of the @_ pass-through feature is to write subroutines whose main job it is to call other subroutines for you. For further details, see perlsub.

How do I create a switch or case statement?

In Perl 5.10, use the given-when construct described in perlsyn:

  1. 	use 5.010;
  3. 	given ( $string ) {
  4. 		when( 'Fred' )        { say "I found Fred!" }
  5. 		when( 'Barney' )      { say "I found Barney!" }
  6. 		when( /Bamm-?Bamm/ )  { say "I found Bamm-Bamm!" }
  7. 		default               { say "I don't recognize the name!" }
  8. 		};

If one wants to use pure Perl and to be compatible with Perl versions prior to 5.10, the general answer is to use if-elsif-else:

  1. 	for ($variable_to_test) {
  2. 		if    (/pat1/)  { }     # do something
  3. 		elsif (/pat2/)  { }     # do something else
  4. 		elsif (/pat3/)  { }     # do something else
  5. 		else            { }     # default
  6. 		}

Here's a simple example of a switch based on pattern matching, lined up in a way to make it look more like a switch statement. We'll do a multiway conditional based on the type of reference stored in $whatchamacallit:

  1.     SWITCH: for (ref $whatchamacallit) {
  3. 	/^$/		&& die "not a reference";
  5. 	/SCALAR/	&& do {
  6. 				print_scalar($$ref);
  7. 				last SWITCH;
  8. 			};
  10. 	/ARRAY/		&& do {
  11. 				print_array(@$ref);
  12. 				last SWITCH;
  13. 			};
  15. 	/HASH/		&& do {
  16. 				print_hash(%$ref);
  17. 				last SWITCH;
  18. 			};
  20. 	/CODE/		&& do {
  21. 				warn "can't print function ref";
  22. 				last SWITCH;
  23. 			};
  25. 	# DEFAULT
  27. 	warn "User defined type skipped";
  29.     }

See perlsyn for other examples in this style.

Sometimes you should change the positions of the constant and the variable. For example, let's say you wanted to test which of many answers you were given, but in a case-insensitive way that also allows abbreviations. You can use the following technique if the strings all start with different characters or if you want to arrange the matches so that one takes precedence over another, as "SEND" has precedence over "STOP" here:

  1. 	chomp($answer = <>);
  2. 	if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
  3. 	elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
  4. 	elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
  5. 	elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
  6. 	elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }

A totally different approach is to create a hash of function references.

  1. 	my %commands = (
  2. 		"happy" => \&joy,
  3. 		"sad",  => \&sullen,
  4. 		"done"  => sub { die "See ya!" },
  5. 		"mad"   => \&angry,
  6. 	);
  8. 	print "How are you? ";
  9. 	chomp($string = <STDIN>);
  10. 	if ($commands{$string}) {
  11. 		$commands{$string}->();
  12. 	} else {
  13. 		print "No such command: $string\n";
  14. 	}

Starting from Perl 5.8, a source filter module, Switch , can also be used to get switch and case. Its use is now discouraged, because it's not fully compatible with the native switch of Perl 5.10, and because, as it's implemented as a source filter, it doesn't always work as intended when complex syntax is involved.

How can I catch accesses to undefined variables, functions, or methods?

The AUTOLOAD method, discussed in Autoloading in perlsub and AUTOLOAD: Proxy Methods in perltoot, lets you capture calls to undefined functions and methods.

When it comes to undefined variables that would trigger a warning under use warnings , you can promote the warning to an error.

  1. 	use warnings FATAL => qw(uninitialized);

Why can't a method included in this same file be found?

Some possible reasons: your inheritance is getting confused, you've misspelled the method name, or the object is of the wrong type. Check out perltoot for details about any of the above cases. You may also use print ref($object) to find out the class $object was blessed into.

Another possible reason for problems is because you've used the indirect object syntax (eg, find Guru "Samy" ) on a class name before Perl has seen that such a package exists. It's wisest to make sure your packages are all defined before you start using them, which will be taken care of if you use the use statement instead of require. If not, make sure to use arrow notation (eg., Guru->find("Samy") ) instead. Object notation is explained in perlobj.

Make sure to read about creating modules in perlmod and the perils of indirect objects in Method Invocation in perlobj.

How can I find out my current or calling package?

(contributed by brian d foy)

To find the package you are currently in, use the special literal __PACKAGE__ , as documented in perldata. You can only use the special literals as separate tokens, so you can't interpolate them into strings like you can with variables:

  1. 	my $current_package = __PACKAGE__;
  2. 	print "I am in package $current_package\n";

If you want to find the package calling your code, perhaps to give better diagnostics as Carp does, use the caller built-in:

  1. 	sub foo {
  2. 		my @args = ...;
  3. 		my( $package, $filename, $line ) = caller;
  5. 		print "I was called from package $package\n";
  6. 		);

By default, your program starts in package main , so you should always be in some package unless someone uses the package built-in with no namespace. See the package entry in perlfunc for the details of empty packages.

This is different from finding out the package an object is blessed into, which might not be the current package. For that, use blessed from Scalar::Util , part of the Standard Library since Perl 5.8:

  1. 	use Scalar::Util qw(blessed);
  2. 	my $object_package = blessed( $object );

Most of the time, you shouldn't care what package an object is blessed into, however, as long as it claims to inherit from that class:

  1. 	my $is_right_class = eval { $object->isa( $package ) }; # true or false

And, with Perl 5.10 and later, you don't have to check for an inheritance to see if the object can handle a role. For that, you can use DOES , which comes from UNIVERSAL :

  1. 	my $class_does_it = eval { $object->DOES( $role ) }; # true or false

You can safely replace isa with DOES (although the converse is not true).

How can I comment out a large block of Perl code?

(contributed by brian d foy)

The quick-and-dirty way to comment out more than one line of Perl is to surround those lines with Pod directives. You have to put these directives at the beginning of the line and somewhere where Perl expects a new statement (so not in the middle of statements like the # comments). You end the comment with =cut , ending the Pod section:

  1. 	=pod
  3. 	my $object = NotGonnaHappen->new();
  5. 	ignored_sub();
  7. 	$wont_be_assigned = 37;
  9. 	=cut

The quick-and-dirty method only works well when you don't plan to leave the commented code in the source. If a Pod parser comes along, you're multiline comment is going to show up in the Pod translation. A better way hides it from Pod parsers as well.

The =begin directive can mark a section for a particular purpose. If the Pod parser doesn't want to handle it, it just ignores it. Label the comments with comment . End the comment using =end with the same label. You still need the =cut to go back to Perl code from the Pod comment:

  1. 	=begin comment
  3. 	my $object = NotGonnaHappen->new();
  5. 	ignored_sub();
  7. 	$wont_be_assigned = 37;
  9. 	=end comment
  11. 	=cut

For more information on Pod, check out perlpod and perlpodspec.

How do I clear a package?

Use this code, provided by Mark-Jason Dominus:

  1. 	sub scrub_package {
  2. 		no strict 'refs';
  3. 		my $pack = shift;
  4. 		die "Shouldn't delete main package"
  5. 			if $pack eq "" || $pack eq "main";
  6. 		my $stash = *{$pack . '::'}{HASH};
  7. 		my $name;
  8. 		foreach $name (keys %$stash) {
  9. 			my $fullname = $pack . '::' . $name;
  10. 			# Get rid of everything with that name.
  11. 			undef $$fullname;
  12. 			undef @$fullname;
  13. 			undef %$fullname;
  14. 			undef &$fullname;
  15. 			undef *$fullname;
  16. 	}
  17. 	}

Or, if you're using a recent release of Perl, you can just use the Symbol::delete_package() function instead.

How can I use a variable as a variable name?

Beginners often think they want to have a variable contain the name of a variable.

  1. 	$fred    = 23;
  2. 	$varname = "fred";
  3. 	++$$varname;         # $fred now 24

This works sometimes, but it is a very bad idea for two reasons.

The first reason is that this technique only works on global variables. That means that if $fred is a lexical variable created with my() in the above example, the code wouldn't work at all: you'd accidentally access the global and skip right over the private lexical altogether. Global variables are bad because they can easily collide accidentally and in general make for non-scalable and confusing code.

Symbolic references are forbidden under the use strict pragma. They are not true references and consequently are not reference counted or garbage collected.

The other reason why using a variable to hold the name of another variable is a bad idea is that the question often stems from a lack of understanding of Perl data structures, particularly hashes. By using symbolic references, you are just using the package's symbol-table hash (like %main:: ) instead of a user-defined hash. The solution is to use your own hash or a real reference instead.

  1. 	$USER_VARS{"fred"} = 23;
  2. 	$varname = "fred";
  3. 	$USER_VARS{$varname}++;  # not $$varname++

There we're using the %USER_VARS hash instead of symbolic references. Sometimes this comes up in reading strings from the user with variable references and wanting to expand them to the values of your perl program's variables. This is also a bad idea because it conflates the program-addressable namespace and the user-addressable one. Instead of reading a string and expanding it to the actual contents of your program's own variables:

  1. 	$str = 'this has a $fred and $barney in it';
  2. 	$str =~ s/(\$\w+)/$1/eeg;		  # need double eval

it would be better to keep a hash around like %USER_VARS and have variable references actually refer to entries in that hash:

  1. 	$str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all

That's faster, cleaner, and safer than the previous approach. Of course, you don't need to use a dollar sign. You could use your own scheme to make it less confusing, like bracketed percent symbols, etc.

  1. 	$str = 'this has a %fred% and %barney% in it';
  2. 	$str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all

Another reason that folks sometimes think they want a variable to contain the name of a variable is because they don't know how to build proper data structures using hashes. For example, let's say they wanted two hashes in their program: %fred and %barney, and that they wanted to use another scalar variable to refer to those by name.

  1. 	$name = "fred";
  2. 	$$name{WIFE} = "wilma";     # set %fred
  4. 	$name = "barney";
  5. 	$$name{WIFE} = "betty";	# set %barney

This is still a symbolic reference, and is still saddled with the problems enumerated above. It would be far better to write:

  1. 	$folks{"fred"}{WIFE}   = "wilma";
  2. 	$folks{"barney"}{WIFE} = "betty";

And just use a multilevel hash to start with.

The only times that you absolutely must use symbolic references are when you really must refer to the symbol table. This may be because it's something that can't take a real reference to, such as a format name. Doing so may also be important for method calls, since these always go through the symbol table for resolution.

In those cases, you would turn off strict 'refs' temporarily so you can play around with the symbol table. For example:

  1. 	@colors = qw(red blue green yellow orange purple violet);
  2. 	for my $name (@colors) {
  3. 		no strict 'refs';  # renege for the block
  4. 		*$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
  5. 	}

All those functions (red(), blue(), green(), etc.) appear to be separate, but the real code in the closure actually was compiled only once.

So, sometimes you might want to use symbolic references to directly manipulate the symbol table. This doesn't matter for formats, handles, and subroutines, because they are always global--you can't use my() on them. For scalars, arrays, and hashes, though--and usually for subroutines-- you probably only want to use hard references.

What does "bad interpreter" mean?

(contributed by brian d foy)

The "bad interpreter" message comes from the shell, not perl. The actual message may vary depending on your platform, shell, and locale settings.

If you see "bad interpreter - no such file or directory", the first line in your perl script (the "shebang" line) does not contain the right path to perl (or any other program capable of running scripts). Sometimes this happens when you move the script from one machine to another and each machine has a different path to perl--/usr/bin/perl versus /usr/local/bin/perl for instance. It may also indicate that the source machine has CRLF line terminators and the destination machine has LF only: the shell tries to find /usr/bin/perl<CR>, but can't.

If you see "bad interpreter: Permission denied", you need to make your script executable.

In either case, you should still be able to run the scripts with perl explicitly:

  1. 	% perl script.pl

If you get a message like "perl: command not found", perl is not in your PATH, which might also mean that the location of perl is not where you expect it so you need to adjust your shebang line.

AUTHOR AND COPYRIGHT

Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and other authors as noted. All rights reserved.

This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file are hereby placed into the public domain. You are permitted and encouraged to use this code in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit would be courteous but is not required.

Page index